Shader "UsayaLib/3D/Unlit/TextureLine" {
    Properties {
        _MainTex ("Texture", 2D) = "white" {}
        _Color ("Texture Color", Color) = (1, 1, 1, 1)
        [KeywordEnum(Multiply, Additive)] _LineBlendMode("Line Blend Mode", Int) = 0
        _LineColor ("Line Color", Color) = (1, 1, 1, 1)
        _Slider ("Slider", float) = 0
        _Width ("Width", float) = 1
        _SlopeX ("SlopeX", float) = 1
        _SlopeY ("SlopeY", float) = 1
    }
    SubShader {
        Tags { "RenderType"="Opaque" }
        LOD 100

        Pass {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma multi_compile_fog
            #pragma multi_compile _LINEBLENDMODE_MULTIPLY _LINEBLENDMODE_ADDITIVE

            #include "UnityCG.cginc"

            struct appdata {
                float4 vertex : POSITION;
                float4 color : COLOR;
                float2 uv : TEXCOORD0;
            };

            struct v2f {
                float2 uv : TEXCOORD0;
                float4 color : COLOR;
                UNITY_FOG_COORDS(1)
                float4 vertex : SV_POSITION;
                float3 pos : TEXCOORD1;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;
            fixed4 _Color;
            fixed4 _LineColor;
            float _Slider;
            float _Width;
            float _SlopeX;
            float _SlopeY;

            v2f vert(appdata v){
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                o.color = v.color * _Color;
                UNITY_TRANSFER_FOG(o,o.vertex);
                o.pos = v.vertex;
                return o;
            }

            fixed4 frag(v2f i) : SV_Target {
                fixed4 color = tex2D(_MainTex, i.uv) * i.color;
                float2 pos = i.pos.xy * float2(_SlopeX, _SlopeY);
                float p = pos.x - pos.y + _Slider;
                float4 c = step(-_Width, p) * step(p, _Width) * _LineColor;
#ifdef _LINEBLENDMODE_ADDITIVE
                color.rgb += step(-_Width, p) * step(p, _Width) * _LineColor.rgb * _LineColor.a;
#else
                color.rgb = color.rgb * (1 - c.a) + c.rgb * c.a;
#endif
                UNITY_APPLY_FOG(i.fogCoord, color);
                return color;
            }
            ENDCG
        }
    }
}